" Vim syntax file
" Language:	Nethack Level File
" Maintainer:	Benjamin Schieder <blindcoder@scavenger.homeip.net>
" Last Change:	2005 Jun 06

" For version 5.x: Clear all syntax items
" For version 6.x: Quit when a syntax file was already loaded
if version < 600
  syntax clear
elseif exists("b:current_syntax")
  finish
endif

" comments
syn match desComment /^#.*/
" MAZE: {{{
syn match desMazeTag /^MAZE:.*/ contains=desMazeDesc
syn match desMazeDesc /"[A-Za-z]\+\(-\(strt\|goal\|fila\|filb\|loca\|[0-9]\+\)\)\="/ contained skipwhite nextgroup=desMazeComma
syn match desMazeComma /,/ contained skipwhite nextgroup=desMazeChar
syn match desMazeChar /'.'/ contained skipwhite
" }}}
" FLAGS: {{{
syn match desFlagsTag /^FLAGS:.*/ contains=desFlagsWords
syn keyword desFlagsWords o_lit o_buried noteleport hardfloor nommap arboreal shortsighted spooky lethe phlegethon contained
" }}}
" INIT_MAP: {{{
syn match desInitMapTag /^INIT_MAP:.*/ contains=desInitMapChar1
syn match desInitMapChar1  /'.'/ skipwhite nextgroup=desInitMapComma1 contained
syn match desInitMapComma1 /,/   skipwhite nextgroup=desInitMapChar2 contained
syn match desInitMapChar2  /'.'/ skipwhite nextgroup=desInitMapComma2 contained
syn match desInitMapComma2 /,/   skipwhite nextgroup=desInitMapBool1 contained
syn case ignore
syn match desInitMapBool1  /\(true\|false\)/ skipwhite nextgroup=desInitMapComma3 contained
syn case match
syn match desInitMapComma3 /,/   skipwhite nextgroup=desInitMapBool2 contained
syn case ignore
syn match desInitMapBool2  /\(true\|false\)/ skipwhite nextgroup=desInitMapComma4 contained
syn case match
syn match desInitMapComma4 /,/   skipwhite nextgroup=desInitMapLit contained
syn case ignore
syn match desInitMapLit    /\(\(un\)\=lit\|random\)/ skipwhite nextgroup=desInitMapComma5 contained
syn case match
syn match desInitMapComma5 /,/   skipwhite nextgroup=desInitMapBool3 contained
syn case ignore
syn match desInitMapBool3  /\(true\|false\)/ skipwhite contained
syn case match
" }}}
" GEOMETRY: {{{
syn match desGeometryTag /^GEOMETRY:.*/ contains=desGeometryH
syn case ignore
syn match desGeometryH /\(right\|left\|center\)/ skipwhite nextgroup=desGeometryComma contained
syn case match
syn match desGeometryComma /,/ skipwhite nextgroup=desGeometryV contained
syn case ignore
syn match desGeometryV /\(top\|bottom\|center\)/ skipwhite contained
syn case match
" }}}
" MAP {{{
syn region desMap start="MAP" end="ENDMAP" contains=desMapWater,desMapDoor,desMapThrone,desMapAir,desMapBound,desMapCloud,desMapIce,desMapHiddenCorridor,desMapSink,desMapLava,desMapTree,desMapBars,desMapCorr,desMapRock,desMapWall
syn match desMapWater /\(MA\)\@<![PW{}]/ contained
syn match desMapDoor /[S+]/ contained
syn match desMapThrone /\\/ contained
syn match desMapAir /\(M\)\@<!AP\@!/ contained
syn match desMapBound /B/ contained
syn match desMapCloud /C/ contained
syn match desMapIce /I/ contained
syn match desMapHiddenCorridor /H/ contained
syn match desMapSink /[KZ]/ contained
syn match desMapLava /L/ contained
syn match desMapTree /T/ contained
syn match desMapBars /F/ contained
syn match desMapCorr /[#.]/ contained
syn match desMapRock / / contained
syn match desMapWall /[-|]/ contained
" }}}
" NOMAP {{{
syn match desNoMap /^NOMAP$/
" }}}
" REGION: {{{
syn match desRegion /^REGION:.*/ contains=desRegionCoord
syn match desRegionCoord /([0-9]\{1,2},[0-9]\{1,2},[0-9]\{1,2},[0-9]\{1,2})/ skipwhite nextgroup=desRegionComma1 contained
syn match desRegionComma1 /,/ skipwhite nextgroup=desRegionLit contained
syn case ignore
syn match desRegionLit /\(\(un\)\=lit\|random\)/ skipwhite nextgroup=desRegionComma2 contained
syn case match
syn match desRegionComma2 /,/ skipwhite nextgroup=desRegionType contained
syn match desRegionType /"[^"]*"/ skipwhite nextgroup=desRegionComma3 contained
syn match desRegionComma3 /,/ skipwhite nextgroup=desRegionFilled contained
syn match desRegionFilled /\(un\)\=filled/ skipwhite nextgroup=desRegionComma4 contained
syn match desRegionComma4 /,/ skipwhite nextgroup=desRegionBool contained
syn match desRegionBool /\(true\|false\)/ skipwhite contained
" }}}
if version >= 508 || !exists("did_des_syntax_inits")
  if version < 508
    let did_des_syntax_inits = 1
    command -nargs=+ HiLink hi link <args>
  else
    command -nargs=+ HiLink hi def link <args>
  endif

  HiLink desComment		Comment
" desMaze {{{
  HiLink desMazeTag		Identifier
  HiLink desMazeDesc		String
  HiLink desMazeChar		String
" }}}
" desFlags {{{
  HiLink desFlagsTag		Identifier
  HiLink desFlagsWords		Type
" }}}
" desInitMap {{{
  HiLink desInitMapTag		Identifier
  HiLink desInitMapChar1	String
  HiLink desInitMapChar2	String
  HiLink desInitMapBool1	Boolean
  HiLink desInitMapBool2	Boolean
  HiLink desInitMapBool3	Boolean
  HiLink desInitMapLit		Boolean
" }}} 
" desGeometry {{{
  HiLink desGeometryTag		Identifier
  HiLink desGeometryH		String
  HiLink desGeometryV		String
" }}}
" desMap {{{
  HiLink desMap			Identifier
  hi desColorWater		term=bold ctermfg=DarkBlue ctermbg=Black
  HiLink desMapWater		desColorWater
  hi desColorDoor		term=bold ctermfg=Brown ctermbg=Black
  HiLink desMapDoor		desColorDoor
  hi desColorThrone		term=bold ctermfg=Yellow ctermbg=Black
  HiLink desMapThrone		desColorThrone
  hi desColorAir		term=bold ctermfg=White ctermbg=Black
  HiLink desMapAir		desColorAir
  HiLink desMapCloud		desColorAir
  hi desColorCorr		ctermfg=grey ctermbg=black
  HiLink desMapBound		desColorCorr
  HiLink desMapHiddenCorridor	desColorCorr
  HiLink desMapCorr		desColorCorr
  HiLink desMapWall		desColorCorr
  hi desColorIce		ctermfg=white ctermbg=cyan
  HiLink desMapIce		desColorIce
  hi desColorSink		ctermfg=grey ctermbg=black
  HiLink desMapSink		desColorSink
  hi desColorLava		ctermfg=red ctermbg=black
  HiLink desMapLava		desColorLava
  hi desColorTree		ctermfg=green ctermbg=black
  HiLink desMapTree		desColorTree
  hi desColorBars		ctermfg=cyan ctermbg=black
  HiLink desMapBars		desColorBars
  hi desColorRock		ctermfg=black ctermbg=gray
  HiLink desMapRock		desColorRock
  HiLink desNoMap		Identifier
" }}}
" desRegion {{{
  HiLink desRegion		Identifier
  HiLink desRegionCoord		Number
  HiLink desRegionLit		Boolean
  HiLink desRegionType		String
  HiLink desRegionFilled	Boolean
  HiLink desRegionBool		Boolean
" }}}
  delcommand HiLink
endif

let b:current_syntax = "des"